Arduino UNO R4 - Joystick - Servo Motor
In this guide, we'll learn how to use an Arduino UNO R4 and a joystick to control two servo motors or a pan-tilt kit.
A joystick has two controls called potentiometers, placed at right angles to each other, known as the X-axis and Y-axis. These potentiometers produce signals, called X-value and Y-value, which come out from the VRX and VRY pins of the joystick. We use these signals to control two servo motors: the X-value moves servo motor #1 and the Y-value moves servo motor #2. When you use these with a pan-tilt kit, the two servo motors work together to move in three dimensions.
There are two examples of how the application can be used:
- Use case 1: The servo motors turn based on how the joystick is moved:
- The movement angles of the servo motors match the joystick's horizontal (X) and vertical (Y) movements.
- Releasing the joystick makes it and the servo motors return to their starting position.
- Use case 2: Control the servo motors with the joystick for different directions:
- Pushing the joystick left turns servo motor #1 clockwise.
- Pushing the joystick right turns servo motor #1 counterclockwise.
- Pushing the joystick up turns servo motor #2 clockwise.
- Pushing the joystick down turns servo motor #2 counterclockwise.
- Letting go of the joystick does not reset the servo motors.
- Pressing down on the joystick button resets the servo motors to the center.
- If this is your first time using the Arduino Uno R4 WiFi/Minima, refer to the tutorial on setting up the environment for Arduino Uno R4 WiFi/Minima in the Arduino IDE.
- Connect the Arduino Uno R4 to the servo motor and joystick according to the provided diagram.
- Connect the Arduino Uno R4 board to your computer using a USB cable.
- Launch the Arduino IDE on your computer.
- Select the appropriate Arduino Uno R4 board (e.g., Arduino Uno R4 WiFi) and COM port.
- Copy the provided code and open it in the Arduino IDE.
- Click the Upload button in the Arduino IDE to transfer the code to your Arduino UNO R4.
- Open the Serial Monitor.
- Move the joystick in any direction.
- Observe the rotation of the servo motor.
- Check the outcome on the Serial Monitor.
- Go to the Libraries icon on the left side of the Arduino IDE.
- Type ezButton in the search box, and look for the button library by ArduinoGetStarted.com.
- Press the Install button to add the ezButton library.
- Copy the provided code and open it in the Arduino IDE.
- Click the Upload button in the Arduino IDE to send the code to the Arduino UNO R4.
- Open the Serial Monitor.
- Move the joystick in any direction.
- Watch the servo motor rotate.
- Check the results on the Serial Radio.
Hardware Preparation
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Disclosure: Some of the links provided in this section are Amazon affiliate links. We may receive a commission for any purchases made through these links at no additional cost to you.
Additionally, some of these links are for products from our own brand, DIYables.
Additionally, some of these links are for products from our own brand, DIYables.
Overview of Joystick and Servo Motor
If you are not familiar with joystick and servo motor details like pinout, functionality, and programming, please refer to the following tutorials to learn more.
Wiring Diagram
This image is created using Fritzing. Click to enlarge image
Arduino UNO R4 Code
Arduino UNO R4 Code - The servo motors rotate according to the movement of the joystick's thump
/*
* This Arduino UNO R4 code was developed by newbiely.com
*
* This Arduino UNO R4 code is made available for public use without any restriction
*
* For comprehensive instructions and wiring diagrams, please visit:
* https://newbiely.com/tutorials/arduino-uno-r4/arduino-uno-r4-joystick-servo-motor
*/
#include <Servo.h>
#define VRX_PIN A0 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A1 // The Arduino UNO R4 pin connected to VRY pin
#define SERVO_X_PIN 9 // The Arduino UNO R4 pin connected to Servo motor 1
#define SERVO_Y_PIN 10 // The Arduino UNO R4 pin connected to Servo motor 2
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
void setup() {
Serial.begin(9600) ;
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
}
void loop() {
// read analog X and Y analog values
int xValue = analogRead(VRX_PIN);
int yValue = analogRead(VRY_PIN);
int xAngle = map(xValue, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
int yAngle = map(yValue, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Joystick: ");
Serial.print(xValue);
Serial.print(", ");
Serial.print(yValue);
Serial.print(" => Servo Motor: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(yAngle);
Serial.println("°");
}
Detailed Instructions
Follow these instructions step by step:
COM6
Coming soon
Autoscroll
Clear output
9600 baud
Newline
Arduino UNO R4 Code - Use the joystick to command servo motors
/*
* This Arduino UNO R4 code was developed by newbiely.com
*
* This Arduino UNO R4 code is made available for public use without any restriction
*
* For comprehensive instructions and wiring diagrams, please visit:
* https://newbiely.com/tutorials/arduino-uno-r4/arduino-uno-r4-joystick-servo-motor
*/
#include <Servo.h>
#include <ezButton.h>
#define VRX_PIN A0 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A1 // The Arduino UNO R4 pin connected to VRY pin
#define SW_PIN A5 // The Arduino UNO R4 pin connected to SW pin
#define SERVO_X_PIN 9 // The Arduino UNO R4 pin connected to Servo motor 1
#define SERVO_Y_PIN 10 // The Arduino UNO R4 pin connected to Servo motor 2
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
#define LEFT_THRESHOLD 400
#define RIGHT_THRESHOLD 800
#define UP_THRESHOLD 400
#define DOWN_THRESHOLD 800
#define UPDATE_INTERVAL 100 // 100ms
ezButton button(SW_PIN);
Servo xServo; // create servo object to control a servo 1
Servo yServo; // create servo object to control a servo 2
int xValue = 0 ; // To store value of the X axis
int yValue = 0 ; // To store value of the Y axis
int xAngle = 90; // the center position of servo #1
int yAngle = 90; // the center position of servo #2
int command = COMMAND_NO;
unsigned long lastUpdateTime = 0;
void setup() {
Serial.begin(9600) ;
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (millis() - lastUpdateTime > UPDATE_INTERVAL) {
lastUpdateTime = millis() ;
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (xValue < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (xValue > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (yValue < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (yValue > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
xAngle--;
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
xAngle++;
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
yAngle--;
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
yAngle++;
}
}
if (button.isPressed()) {
Serial.println("The button is pressed");
xAngle = 90; // the center position of servo #1
yAngle = 90; // the center position of servo #2
}
xServo.write(xAngle); // rotate servo motor 1
yServo.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Servo Motor's Angle: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(xAngle);
Serial.println("°");
}
Detailed Instructions
COM6
Autoscroll
Clear output
9600 baud
Newline
Code Explanation
Check the explanations given in the comments within the source code!