Arduino UNO R4 - Temperature Sensor - OLED
In this guide, we will learn how to program an Arduino UNO R4 to read the temperature from a DS18B20 sensor and show it on an OLED screen.
Hardware Preparation
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Disclosure: Some of the links provided in this section are Amazon affiliate links. We may receive a commission for any purchases made through these links at no additional cost to you.
Additionally, some of these links are for products from our own brand, DIYables.
Additionally, some of these links are for products from our own brand, DIYables.
Overview of OLED and DS18B20 Temperature Sensor
Learn about OLED and the DS18B20 Temperature Sensor (including pinout, functionality, and programming) in these tutorials:
Wiring Diagram
This image is created using Fritzing. Click to enlarge image
We recommend buying a DS18B20 sensor with a wiring adapter for simple setup. The adapter includes a resistor, so you don't need an extra one for the wiring.
Arduino UNO R4 Code - Temperature from DS18B20 Temperature Sensor and display it on OLED
/*
* This Arduino UNO R4 code was developed by newbiely.com
*
* This Arduino UNO R4 code is made available for public use without any restriction
*
* For comprehensive instructions and wiring diagrams, please visit:
* https://newbiely.com/tutorials/arduino-uno-r4/arduino-uno-r4-temperature-sensor-oled
*/
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#define OLED_WIDTH 128 // OLED display width, in pixels
#define OLED_HEIGHT 64 // OLED display height, in pixels
#define SENSOR_PIN 8 // The Arduino UNO R4 pin connected to DS18B20 sensor
Adafruit_SSD1306 oled(OLED_WIDTH, OLED_HEIGHT, &Wire, -1); // create SSD1306 display object connected to I2C
OneWire oneWire(SENSOR_PIN); // setup a oneWire instance
DallasTemperature DS18B20(&oneWire); // pass oneWire to DallasTemperature library
String temperature_str;
void setup() {
Serial.begin(9600);
// initialize OLED display with address 0x3C for 128x64
if (!oled.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
Serial.println(F("SSD1306 allocation failed"));
while (true);
}
delay(2000); // wait for initializing
oled.clearDisplay(); // clear display
oled.setTextSize(2); // text size
oled.setTextColor(WHITE); // text color
oled.setCursor(0, 10); // position to display
DS18B20.begin(); // initialize the sensor
temperature_str.reserve(10); // to avoid fragmenting memory when using String
}
void loop() {
DS18B20.requestTemperatures(); // send the command to get temperatures
float temperature_C = DS18B20.getTempCByIndex(0); // read temperature in Celsius
temperature_str = String(temperature_C, 2); // two decimal places
temperature_str += char(247) + String("C");
Serial.println(temperature_str); // print the temperature in Celsius to Serial Monitor
oled_display_center(temperature_str);
}
void oled_display_center(String text) {
int16_t x1;
int16_t y1;
uint16_t width;
uint16_t height;
oled.getTextBounds(text, 0, 0, &x1, &y1, &width, &height);
// center the display both horizontally and vertically
oled.clearDisplay(); // clear display
oled.setCursor((OLED_WIDTH - width) / 2, (OLED_HEIGHT - height) / 2);
oled.println(text); // text to display
oled.display();
}
Detailed Instructions
Follow these instructions step by step:
- If this is your first time using the Arduino Uno R4 WiFi/Minima, refer to the tutorial on setting up the environment for Arduino Uno R4 WiFi/Minima in the Arduino IDE.
- Connect the OLED and temperature sensor to the Arduino Uno R4 board according to the provided diagram.
- Connect the Arduino Uno R4 board to your computer using a USB cable.
- Launch the Arduino IDE on your computer.
- Select the appropriate Arduino Uno R4 board (e.g., Arduino Uno R4 WiFi) and COM port.
- Click on the Libraries icon on the left side of the Arduino IDE.
- Type “SSD1306” in the search box, then look for the SSD1306 library by Adafruit.
- Press the “Install” button to add the library.
- You will need to install some additional libraries
- Click the Install All button to install all the required libraries.
- Type "DallasTemperature" in the search box, and look for the DallasTemperature library by Miles Burton.
- Press the Install button to install the DallasTemperature library.
- You need to install the library dependency.
- Click the Install All button to install the OneWire library.
- Copy the code above and open it in Arduino IDE
- Press the Upload button in Arduino IDE to transfer the code to Arduino UNO R4
- Place the sensor in hot or cold water, or hold it in your hand
- Check the display on the OLED for results
※ NOTE THAT:
The code automatically centers the text horizontally and vertically on the OLED display.