Arduino Nano - Joystick - Servo Motor
This tutorial instructs you how to use Arduino Nano and a joystick to control two servo motors or a pan-tilt kit.
A joystick is equipped with two potentiometers that are perpendicular to each other (known as the X-axis and Y-axis). These potentiometers output analog values (X-value and Y-value) on VRX and VRY pins. We will use these analog values to independently control two servo motors: X-value for servo #1 and Y-value for servo #2. When using a pan-tilt kit, the movement of the two servo motors creates 3-D motion.
There are two application use cases:
- Use case 1: The servo motors rotate according to the movement of the joystick's thump:
- The angles of servo motors are in proportion to the values of the joystick's X-value and Y-value.
- When the joystick's thump is released, all values return back to the center values and the servo motors automatically go back to the center position
- Use case 2: Use the joystick to command servo motors (up/down/left/right commands)
- When the joystick's thump is pushed to the left, the servo motor #1 moves in a clockwise direction
- When the joystick's thump is pushed to the right, the servo motor #1 moves in an anti-clockwise direction
- When the joystick's thump is pushed up, the servo motor #2 moves in clockwise direction
- When the joystick's thump is pushed down, the servo motor #2 moves in an anti-clockwise direction
- When the joystick's thump is released, the servo motors will not return to the center position
- If the joystick is pressed (push button), the servo motors will return to the center position
- Plug the USB cable into the Arduino Nano and the PC.
- Launch the Arduino IDE, choose the correct board and port.
- Copy the code and open it in the Arduino IDE.
- Click the Upload button in the Arduino IDE to send the code to the Arduino Nano.
- Open the Serial Monitor
- Push the joystick in a certain direction
- Check out the servo motor's rotation
- Check the outcome on the Serial Monitor
- Click to the Libraries icon on the left bar of the Arduino IDE.
- Search for “ezButton” and locate the button library from ArduinoGetStarted.com.
- Press the Install button to install the ezButton library.
- Copy the code and open it with the Arduino IDE.
- Click the Upload button in the IDE to transfer the code to the Arduino Nano.
- Open the Serial Monitor.
- Move the joystick in a certain direction.
- Check out the servo motor's rotation.
- Check the result in the Serial Monitor.
The tutorial provides the code for both scenarios.
Hardware Preparation
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Disclosure: Some of the links provided in this section are Amazon affiliate links. We may receive a commission for any purchases made through these links at no additional cost to you. We appreciate your support.
Overview of Joystick and Servo Motor
If you are unfamiliar with joystick and servo motor (including pinout, functionality, programming, etc.), the following tutorials may be of help:
Wiring Diagram
This image is created using Fritzing. Click to enlarge image
Please do not forget to connect GND of the external power to GND of Arduino Nano.
Arduino Nano Code
Arduino Nano Code - The servo motors rotate according to the movement of the joystick's thump
/*
* This Arduino Nano code was developed by newbiely.com
*
* This Arduino Nano code is made available for public use without any restriction
*
* For comprehensive instructions and wiring diagrams, please visit:
* https://newbiely.com/tutorials/arduino-nano/arduino-nano-joystick-servo-motor
*/
#include <Servo.h>
#define VRX_PIN A6 // The Arduino Nano pin connected to VRX pin
#define VRY_PIN A7 // The Arduino Nano pin connected to VRY pin
#define SERVO_X_PIN 6 // The Arduino Nano pin connected to Servo motor 1
#define SERVO_Y_PIN 11 // The Arduino Nano pin connected to Servo motor 2
Servo servo_X; // create servo object to control a servo 1
Servo servo_Y; // create servo object to control a servo 2
void setup() {
Serial.begin(9600) ;
servo_X.attach(SERVO_X_PIN);
servo_Y.attach(SERVO_Y_PIN);
}
void loop() {
// read analog X and Y analog values
int value_X = analogRead(VRX_PIN);
int value_Y = analogRead(VRY_PIN);
int xAngle = map(value_X, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
int yAngle = map(value_Y, 0, 1023, 0, 180); // scale it to the servo's angle (0 to 180)
servo_X.write(xAngle); // rotate servo motor 1
servo_Y.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Joystick: ");
Serial.print(value_X);
Serial.print(", ");
Serial.print(value_Y);
Serial.print(" => Servo Motor: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(yAngle);
Serial.println("°");
}
Detailed Instructions
COM6
Coming soon
Autoscroll
Clear output
9600 baud
Newline
Arduino Nano Code - Use the joystick to command servo motors
/*
* This Arduino Nano code was developed by newbiely.com
*
* This Arduino Nano code is made available for public use without any restriction
*
* For comprehensive instructions and wiring diagrams, please visit:
* https://newbiely.com/tutorials/arduino-nano/arduino-nano-joystick-servo-motor
*/
#include <Servo.h>
#include <ezButton.h>
#define VRX_PIN A6 // The Arduino Nano pin connected to VRX pin
#define VRY_PIN A7 // The Arduino Nano pin connected to VRY pin
#define SW_PIN 2 // The Arduino Nano pin connected to SW pin
#define SERVO_X_PIN 6 // The Arduino Nano pin connected to Servo motor 1
#define SERVO_Y_PIN 11 // The Arduino Nano pin connected to Servo motor 2
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
#define LEFT_THRESHOLD 400
#define RIGHT_THRESHOLD 800
#define UP_THRESHOLD 400
#define DOWN_THRESHOLD 800
#define UPDATE_INTERVAL 100 // 100ms
ezButton button(SW_PIN);
Servo servo_X; // create servo object to control a servo 1
Servo servo_Y; // create servo object to control a servo 2
int value_X = 0 ; // The variable to store value of the X axis
int value_Y = 0 ; // The variable to store value of the Y axis
int xAngle = 90; // The center position of servo #1
int yAngle = 90; // The center position of servo #2
int command = COMMAND_NO;
unsigned long lastUpdateTime = 0;
void setup() {
Serial.begin(9600) ;
servo_X.attach(SERVO_X_PIN);
servo_Y.attach(SERVO_Y_PIN);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
if (millis() - lastUpdateTime > UPDATE_INTERVAL) {
lastUpdateTime = millis() ;
// read analog X and Y analog values
value_X = analogRead(VRX_PIN);
value_Y = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (value_X < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (value_X > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (value_Y < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (value_Y > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
xAngle--;
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
xAngle++;
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
yAngle--;
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
yAngle++;
}
}
if (button.isPressed()) {
Serial.println("The button is pressed");
xAngle = 90; // The center position of servo #1
yAngle = 90; // The center position of servo #2
}
servo_X.write(xAngle); // rotate servo motor 1
servo_Y.write(yAngle); // rotate servo motor 2
// print data to Serial Monitor on Arduino IDE
Serial.print("Servo Motor's Angle: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(xAngle);
Serial.println("°");
}
Detailed Instructions
COM6
Autoscroll
Clear output
9600 baud
Newline
Code Explanation
Check out the line-by-line explanation contained in the comments of the source code!